[Terraform+AWS]Pythonツールのインフラ(AWS)をTerraformで構築した話

・
├──main.tf　⇒メインファイル
├──terraform.tfvars　⇒メインファイルで使用する変数定義（アクセスキー等を記述するためGit等で公開する際には注意）
├──modules
|　├──iam
|　|　└──iam.tf　⇒IAMの実装
|　├──lambda
|　|　└──lambda.tf　⇒Lambdaの実装
|　|　└──variable.tf　⇒lambda.tfで使用する変数定義
|　└──eventbridge
|　 　└──eventbridge.tf　⇒EventBridgeの実装
|　 　└──variable.tf　⇒variable.tfで使用する変数定義
|　└──s3
|　 　└──s3.tf　⇒S3の実装
├──app
|　└──lambda_function.py　⇒Lambdaで実行するPythonコード
└──archive
 　└──lambda.zip　⇒Lambdaで実行するzipファイル（appディレクトリの中をzip化したもの）

#awsアクセスキー
variable aws_access_key_id {}
variable aws_secret_access_key {}
#Lambda環境変数（twitterAPIキー）
variable twitter_access_token_key {}
variable twitter_access_token_key_secret {}
variable twitter_consumer_key {}
variable twitter_consumer_key_secret {}

#Terraformバージョン
terraform {
    required_version = "~> 0.12.5"
}

#プロバイダ情報
provider aws {
    version = "3.37.0"
    access_key = var.aws_access_key_id
    secret_key = var.aws_secret_access_key
    region = "ap-northeast-1"   
}
provider archive {
    version = "2.1.0"
}

#IAM
module iam {
    source = "./modules/iam"
}

#Lambda
module lambda {
    source = "./modules/lambda"
    role_arn = module.iam.lambda_role_arn
    policy = module.iam.lambda_policy
    twi_access_token_key = var.twitter_access_token_key
    twi_access_token_key_secret = var.twitter_access_token_key_secret
    twi_consumer_key = var.twitter_consumer_key
    twi_consumer_key_secret = var.twitter_consumer_key_secret
}

#Eventbridge
module cloudwatch_event {
    source = "./modules/eventbridge"
    lambda_arn = module.lambda.arn
    lambda_function_name = module.lambda.function_name
}

#S3
module s3 {
    source = "./modules/s3"
}

aws_access_key_id = "（AWSのアクセスキー）"
aws_secret_access_key = "（AWSのシークレットアクセスキー）"
twitter_access_token_key = "（TwitterAPIのアクセストークンキー）"
twitter_access_token_key_secret = "（TwitterAPIのシークレットアクセストークンキー）"
twitter_consumer_key = "（TwitterAPIのコンシューマキー）"
twitter_consumer_key_secret = "（TwitterAPIのシークレットコンシューマキー）"

#IAM
#信頼ポリシー(lambdaがこのロールを受け取れるようにする)
data aws_iam_policy_document assume_role {
    statement {
        actions = ["sts:AssumeRole"]
        effect  = "Allow"
        principals {
            type = "Service"
            identifiers = ["lambda.amazonaws.com"]
        }
    }
}

#IAMロールの作成
resource aws_iam_role lambda_role {
    name = "MyLambdaRole"
    assume_role_policy = data.aws_iam_policy_document.assume_role.json
}

#IAMポリシー（AWSLambdaBasicExecutionRole）
data aws_iam_policy lambda_basic_execution {
    arn = "arn:aws:iam::aws:policy/service-role/AWSLambdaBasicExecutionRole"
}
data aws_iam_policy s3_full_access {
    arn = "arn:aws:iam::aws:policy/AmazonS3FullAccess"
}

#IAMロールへのIAMポリシーのアタッチ
resource aws_iam_role_policy_attachment lambda_basic_execution {
    role = aws_iam_role.lambda_role.name
    policy_arn = data.aws_iam_policy.lambda_basic_execution.arn
}
resource aws_iam_role_policy_attachment s3_access {
    role = aws_iam_role.lambda_role.name
    policy_arn = data.aws_iam_policy.s3_full_access.arn
}

#Lambdaで使用する値のアウトプット
output lambda_role_arn {
    value = aws_iam_role.lambda_role.arn
}
output lambda_policy {
    value = aws_iam_role_policy_attachment.s3_access
}

#Lambda
#定数定義
locals {
    function_name  = "terraform_bangdre_function"
}

#lambda実行ファイル定義
data archive_file function_source {
    type = "zip"
    source_dir = "app"
    output_path = "archive/lambda.zip"
}

#lambda作成
resource aws_lambda_function function {
    function_name = local.function_name
    handler = "lambda_function.lambda_handler"
    runtime = "python3.8"
    timeout = 15
    filename = data.archive_file.function_source.output_path
    source_code_hash = data.archive_file.function_source.output_base64sha256
    role = var.role_arn
    depends_on = [var.policy, aws_cloudwatch_log_group.lambda_log_group]
    environment {
        variables = {
            ACCESS_TOKEN_KEY = "${var.twi_access_token_key}"
            ACCESS_TOKEN_KEY_SECRET = "${var.twi_access_token_key_secret}"
            CONSUMER_KEY = "${var.twi_consumer_key}"
            CONSUMER_KEY_SECRET = "${var.twi_consumer_key_secret}"
            TZ = "Asia/Tokyo"
        }
    }
}

#CloudWatchLogsグループ定義
resource aws_cloudwatch_log_group lambda_log_group {
    name = "/aws/lambda/${local.function_name}"
}

#EventBridgeで使用する値のアウトプット
output arn {
    value = aws_lambda_function.function.arn
}
output function_name {
    value = aws_lambda_function.function.function_name
}

variable role_arn {}
variable policy {}
variable twi_access_token_key {}
variable twi_access_token_key_secret {}
variable twi_consumer_key {}
variable twi_consumer_key_secret {}

#EventBridge
#ルール作成
resource aws_cloudwatch_event_rule event_rule {
    name = "cron-lambda-terraform"
    schedule_expression = "cron(0 11,15 * * ? *)"
}

#Lambdaアクセス権限付与
resource aws_cloudwatch_event_target event_target {
    rule = aws_cloudwatch_event_rule.event_rule.name
    arn  = var.lambda_arn
}

#EventbridgeとLambda関数への結び付け
resource aws_lambda_permission allow_cloudwatch {
    statement_id  = "AllowExecutionFromCloudWatch"
    action = "lambda:InvokeFunction"
    function_name = var.lambda_function_name
    principal = "events.amazonaws.com"
    source_arn = aws_cloudwatch_event_rule.event_rule.arn
}

variable lambda_arn {}
variable lambda_function_name {}

#S3
#バケット作成
resource aws_s3_bucket bucket {
    bucket = "bangdream-eventlist-terraform"
    acl    = "private"
    versioning {
        enabled = false
    }
}

#作業フォルダの初期化、必要なproviderやmoduleの読み込み
terraform init
#実行した際にどうなるかの検証
terraform plan
#実行
terraform apply